Как в ячейку вложить несколько элементов из раскрывающегося списка excel

VBA. Для этого нужно сделать форму с (раскрывающимся) списком с множественным выбором. Выбранные значения вставлять в ячейку, объединив их в строку с нужным разделителем.

На форму добавить ListBox и 2 CommandButton - Ok и Cancel. Установить ListBox1.MultiSelect = fmMultiSelectMulti.

Код формы:

Private Sub CommandButton1_Click()
  sResult = ""
  With ListBox1
    For i = 0 To .ListCount - 1
      If .Selected(i) Then sResult = sResult + ";" + .List(i)
    Next
    If sResult <> "" Then sResult = Mid$(sResult, 2)
  End With
  Me.Hide
End Sub

Private Sub CommandButton2_Click()
  sResult = ""
  Me.Hide
End Sub

Private Sub UserForm_Activate()
  With ListBox1
    For i = 0 To .ListCount - 1
      .Selected(i) = False
    Next
  End With
End Sub

Private Sub UserForm_Initialize()
  ListBox1.AddItem "qwe"
  ListBox1.AddItem "rty"
  ListBox1.AddItem "asd"
  ListBox1.AddItem "fgh"
  ListBox1.AddItem "zxc"
  ListBox1.AddItem "vbn"
End Sub

Код листа:

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
  UserForm1.Show vbModal
  If sResult <> "" Then Target = sResult
  Cancel = True
End Sub

Код модуля:

Public sResult As String

Выбрать любой удобный способ отображения формы. Двойной щелчок на листе использован для демонстрации.

Можно вставить список прямо на рабочий лист и заполнять активную ячейку по нажатию кнопки, предварительно выбрав элементы в списке. Элементы списка брать из диапазона ячеек. Зафиксировать верхнюю область листа и разместить на ней необходимые элементы управления.

Выбранное значение из выпадающего списка добавляется в ячейку с этим списком. Удаление текста - двойной клик по ячейке.

В модуль листа:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim oldValue As String

    If Application.Intersect(Range("B2"), Target) Is Nothing Then Exit Sub

    Application.EnableEvents = False

    Application.Undo
    oldValue = Target.Value
    Application.Undo
    Target.Value = fNormal(oldValue & " " & Target.Value)

    Application.EnableEvents = True
End Sub

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Application.Intersect(Range("B2"), Target) Is Nothing Then Exit Sub

    Application.EnableEvents = False
    Target.ClearContents
    Application.EnableEvents = True
End Sub

Private Function fNormal(sText As String) As String
    fNormal = Replace(Application.Trim(Replace(sText, ",", " ")), " ", ", ")
End Function

Строку можно выводить в другую ячейку (например, C4). При таком варианте строк кода в два раза меньше:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim oldValue As String

    If Application.Intersect(Range("B2"), Target) Is Nothing Then Exit Sub

    Application.EnableEvents = False
    Range("B4").Value = fNormal(Range("B4").Value & " " & Target.Value)
    Application.EnableEvents = True
End Sub

Private Function fNormal(sText As String) As String
    fNormal = Replace(Application.Trim(Replace(sText, ",", " ")), " ", ", ")
End Function