Не работает формула SUMIFS() вместе с IMPORTRANGE()

Рейтинг: 2Ответов: 1Опубликовано: 23.01.2015

Задача: есть 2 документа, необходимо суммировать сумму ячеек в одном документе при соответствии данных следующим значениям: 1) дата; 2) тип товара, и вывести значение суммы в ячейку в другом документе.

В формуле я пишу следующее:

=sumifs(importrange("1_zEtFp5vEQyMhnM2ryfVIXlSI9WNABfnbG46NOQb-cA"; "Январь!D:D"); importrange("1_zEtFp5vEQyMhnM2ryfVIXlSI9WNABfnbG46NOQb-cA"; "Январь!A:A"); "=21.01.2015"; importrange("1_zEtFp5vEQyMhnM2ryfVIXlSI9WNABfnbG46NOQb-cA"; "Январь!C:C"); "=Дизель")

Однако программа пишет в ячейке #N/A, а при наведении показывает

Ошибка: В качестве аргумента необходимо указать диапазон ячеек.

google-spreadsheet
Источник: Stack Overflow на русском

Ответы

▲ 1

Комментарий

Ваша ошибка в том, что вы передаете в формулу, которая ожидает массив, неизвестное содержимое. Содержимое неизвестно, потому что оно еще не возвращено. Да, и условия записаны неверно.

Дано

К сожалению, вы не привели пример, поэтому будет мой вариант. Пусть дана Таблица с id = 17enVVxq5roVdusG8zOnK03Dfyiquk2RIVmAuVLkHexM с листом "Данные"

+---+------------+-----+--------+
|   |     A      |  B  |   C    |
+---+------------+-----+--------+
| 1 | 01.01.2015 | 532 | ДИЗЕЛЬ |
| 2 | 02.01.2015 | 434 | БЕНЗИН |
| 3 | 01.01.2015 | 477 | ДИЗЕЛЬ |
| 4 | 04.01.2015 | 356 | БЕНЗИН |
| 5 | 05.01.2015 | 331 | ДИЗЕЛЬ |
+---+------------+-----+--------+

Необходимо во второй Таблице получить сумму всех B, где A = "1/1/2015" и C = "ДИЗЕЛЬ".

Решение

Вариант 1

Если решать по предложенному варианту, то сперва необходимо получить данные во вторую Таблицу (формула прописана в ячейке B1 второй Таблицы)

=IMPORTRANGE("17enVVxq5roVdusG8zOnK03Dfyiquk2RIVmAuVLkHexM"; "Данные!A1:C20")

И только после этого делать расчет

=SUMIFS(C:C;B:B;"1/1/2015";D:D;"ДИЗЕЛЬ")

Вариант 2

Для любителей "сочных" решений со вложенными вариантами, вероятнее всего, подойдет решение через QUERY()

=QUERY(IMPORTRANGE("17enVVxq5roVdusG8zOnK03Dfyiquk2RIVmAuVLkHexM"; "Данные!A:C");"select sum(Col2) where Col1 = date '2015-01-01' and Col3 = 'ДИЗЕЛЬ' label sum(Col2) 'СУММА'")

Этот способ вернет две строки: заголовок и результат.

Материалы